@ GMM2S.SET @

@------------------------------------------------------------------------------
Prepared by Lars P. Hansen, Masao Ogaki, and John C. Heaton
    Financial support from the National Science Foundation
                 Grant number: SES-8512371

 Last Revision:  05/29/91
------------------------------------------------------------------------------@
/*
This program has been used and seem to be free of errors. However,
we (Lars P. Hansen, John C. Heaton, and Masao Ogaki) do not assume
responsibility for any remaining errors.  In no event shall we be liable to
for any damages whatsoever arising out ot the use of or inability to use
this program.

   @@ This program sets procedure GMM2S.  See GMM2S.EXP for documentation.
      GMM2S.EXP is also an example file.  This is for 2-Step GMM estimation.
*/
#include "partinv.prc";
#include "ywp.prc";
@ Globals @
clear bgm,const,const2,W0,gufn,w0flag,calwflag,nv,ordard;
lend=15;

proc hu(b); @ This is a dummy definition, and not used by GMM programs.@
retp(b);
endp;

proc sohu2(b12); @ This is a dummy definition, and not used by GMM programs.@
retp(b12);
endp;

proc (1)=ufn(b);
retp(const*sumc(hu(b)));
endp;

proc startval;
retp(bgm);
endp;

proc gmm2s(&gradq,bgm1,del1,hu1,tend,nzv,w0flag,zero,maxitegm);
local gradq:proc;
local kgm,gam2,gam21,gam22,gdi,omestr,kgm1,
      L,nz,maxrw,df,chi,differ,itergm,vbgm,sd,prob,wzp,omega22,tau,ometau,
      snzi,snzi0,igm,w,vp,prob0,differp,
      bmai,i,ib,ie,rzw,rv,rvwz,ep,tma,xpx,ypx,bma,arcoef,omega2;
clear omega22;
kgm=rows(bgm);
kgm1=rows(bgm1);
L=sumc(nzv);
? "Initial values of the coefficients=" bgm';
? "1st Step GMM" bgm1';
format /m1 16,8;
df=L-kgm;
prob0=100;
clear chi;
differ=1e+12;
differp=differ;
if w0flag==1;
 clear w0;
 ? "initial values of parameters are used to caluculate initial W0";
 itergm=0;
 goto lab100;
elseif w0flag==0;
 w0=eye(L);
 ? "Initial W0=I";
 ? "Scaling Constant used for first iteration=" const;
 itergm=1;
 bgm=minquad;
 gam2=gradq(&sohu2,bgm1|bgm,sohu2(bgm1|bgm),0);
 gam21=gam2[.,1:kgm1]/tend;
 save bgmi=bgm;
 goto lab100;
endif;
? "W0 in the memory is used as initial W0";
itergm=1;
const=const2;
if w0flag==3;
 vof=ofn(bgm);
? "W0 and bgm in the memory is used for the first GMM result";
 goto lab3200;
endif;
? "W0 in the memory is used for the first GMM result";
do until differ<zero;
     save omega=omega22;
     save w0;
     const=const2;
     bgm=minquad;
     save bgm;
lab3200:
output on;
 gam2=gradq(&sohu2,bgm1|bgm,sohu2(bgm1|bgm),0);
 gam21=gam2[.,1:kgm1]/tend;
 gam22=gam2[.,kgm1+1:kgm1+kgm];
 vbgm=tend*invpd(gam22'w0*gam22);
 sd=sqrt(diag(vbgm));
 save varb=vbgm;
   @ save variance for bgm [not sqrt(T)*bgm] in VARB.FMT @
? "
================= GMM ITERATION " itergm "====================";
 ? "   b=" bgm';
 ? "   s.d.=" sd';
   if df>0;

    chi=(vof)./((const^2).*tend);
    prob=cdfchic(chi,df);
    differp=abs(prob-prob0);
    prob0=prob;
 ? "   chi square=" chi "(" prob ")";
 ? "   d.f.=" df;
 ? "   difference in prob. value from last GMM iteration=" differp;
 elseif df==0;? "   Just Identified";
 else;? "   L<kgm; Not Identified";endif;
 ? "   scaling const used is" const;
 if itergm>maxitegm-0.5;  @ or differp<zero;@
  goto labe;
 endif;
 lab100:
 wzp=hu1~hu(bgm);
 omega22=wzp'wzp;
 gdi=(-gam21*del1)~eye(L);
 omestr=gdi*omega22*(gdi');
 trap 1;
 w=invpd(omestr);
 trap 0;
 if not scalerr(w);
  goto lnexite;
 endif;
  ? "!!!!! ERROR !!!!! OMEGA should be p.s.d. but is not p.d.";
  output off;
  stop;
@ Next Iteration over W0 @
lnexite:
 differ=w-w0;differ=maxc(maxc(abs(differ)));
 ? "   max(|difference|)=" differ;
 w0=w;
 itergm=itergm+1;
endo;
labe:
retp(chi);
endp;
@ ------------------------ End of Program ------------------------------ @